image generation
There is no browser build of this example yet.
Is it the same as C?
- Desktop:verified The Zig version renders a final frame that is byte-identical to the C example.
- Browser:not checked yet The browser comparison does not cover this example yet.
//! raylib [textures] example - image generation
//!
//! Zig-API translation of examples/textures/textures_image_generation.c (raylib 6.2).
//! Example contributed by Wilhem Barbier (@nounoursheureux) and reviewed by Ramon Santamaria (@raysan5)
//! Example licensed under an unmodified zlib/libpng license.
//! Copyright (c) 2017-2025 Wilhem Barbier (@nounoursheureux) and Ramon Santamaria (@raysan5)
const rl = @import("raylib");
/// On-screen label of each generated texture
const Label = struct { text: [:0]const u8, x: i32, color: rl.Color };
// Currently we have 8 generation algorithms but some have multiple purposes (Linear and Square Gradients)
const labels = [_]Label{
.{ .text = "VERTICAL GRADIENT", .x = 560, .color = .ray_white },
.{ .text = "HORIZONTAL GRADIENT", .x = 540, .color = .ray_white },
.{ .text = "DIAGONAL GRADIENT", .x = 540, .color = .ray_white },
.{ .text = "RADIAL GRADIENT", .x = 580, .color = .light_gray },
.{ .text = "SQUARE GRADIENT", .x = 580, .color = .light_gray },
.{ .text = "CHECKED", .x = 680, .color = .ray_white },
.{ .text = "WHITE NOISE", .x = 640, .color = .red },
.{ .text = "PERLIN NOISE", .x = 640, .color = .red },
.{ .text = "CELLULAR", .x = 670, .color = .ray_white },
};
pub fn main() !void {
// Initialization
const screen_width = 800;
const screen_height = 450;
rl.initWindow(screen_width, screen_height, "raylib [textures] example - image generation");
defer rl.closeWindow(); // Close window and OpenGL context
const images = [labels.len]rl.Image{
rl.genImageGradientLinear(screen_width, screen_height, 0, .red, .blue), // vertical
rl.genImageGradientLinear(screen_width, screen_height, 90, .red, .blue), // horizontal
rl.genImageGradientLinear(screen_width, screen_height, 45, .red, .blue), // diagonal
rl.genImageGradientRadial(screen_width, screen_height, 0.0, .white, .black),
rl.genImageGradientSquare(screen_width, screen_height, 0.0, .white, .black),
rl.genImageChecked(screen_width, screen_height, 32, 32, .red, .blue),
rl.genImageWhiteNoise(screen_width, screen_height, 0.5),
rl.genImagePerlinNoise(screen_width, screen_height, 50, 50, 4.0),
rl.genImageCellular(screen_width, screen_height, 32),
};
var textures: [labels.len]rl.Texture2D = undefined;
var loaded: usize = 0;
// Unload textures data (GPU VRAM)
defer for (textures[0..loaded]) |texture| rl.unloadTexture(texture);
for (images) |image| {
textures[loaded] = try rl.loadTextureFromImage(image);
loaded += 1;
}
// Unload image data (CPU RAM)
for (images) |image| rl.unloadImage(image);
var current_texture: usize = 0;
rl.setTargetFPS(60);
// Main game loop
while (!rl.windowShouldClose()) {
// Update
if (rl.isMouseButtonPressed(.left) or rl.isKeyPressed(.right)) {
current_texture = (current_texture + 1) % textures.len; // Cycle between the textures
}
// Draw
rl.beginDrawing();
defer rl.endDrawing();
rl.clearBackground(.ray_white);
rl.drawTexture(textures[current_texture], 0, 0, .white);
rl.drawRectangle(30, 400, 325, 30, rl.fade(.sky_blue, 0.5));
rl.drawRectangleLines(30, 400, 325, 30, rl.fade(.white, 0.5));
rl.drawText("MOUSE LEFT BUTTON to CYCLE PROCEDURAL TEXTURES", 40, 410, 10, .white);
const label = labels[current_texture];
rl.drawText(label.text, label.x, 10, 20, label.color);
}
}/*******************************************************************************************
*
* raylib [textures] example - image generation
*
* Example complexity rating: [★★☆☆] 2/4
*
* Example originally created with raylib 1.8, last time updated with raylib 1.8
*
* Example contributed by Wilhem Barbier (@nounoursheureux) and reviewed by Ramon Santamaria (@raysan5)
*
* Example licensed under an unmodified zlib/libpng license, which is an OSI-certified,
* BSD-like license that allows static linking with closed source software
*
* Copyright (c) 2017-2025 Wilhem Barbier (@nounoursheureux) and Ramon Santamaria (@raysan5)
*
********************************************************************************************/
#include "raylib.h"
#define NUM_TEXTURES 9 // Currently we have 8 generation algorithms but some have multiple purposes (Linear and Square Gradients)
//------------------------------------------------------------------------------------
// Program main entry point
//------------------------------------------------------------------------------------
int main(void)
{
// Initialization
//--------------------------------------------------------------------------------------
const int screenWidth = 800;
const int screenHeight = 450;
InitWindow(screenWidth, screenHeight, "raylib [textures] example - image generation");
Image verticalGradient = GenImageGradientLinear(screenWidth, screenHeight, 0, RED, BLUE);
Image horizontalGradient = GenImageGradientLinear(screenWidth, screenHeight, 90, RED, BLUE);
Image diagonalGradient = GenImageGradientLinear(screenWidth, screenHeight, 45, RED, BLUE);
Image radialGradient = GenImageGradientRadial(screenWidth, screenHeight, 0.0f, WHITE, BLACK);
Image squareGradient = GenImageGradientSquare(screenWidth, screenHeight, 0.0f, WHITE, BLACK);
Image checked = GenImageChecked(screenWidth, screenHeight, 32, 32, RED, BLUE);
Image whiteNoise = GenImageWhiteNoise(screenWidth, screenHeight, 0.5f);
Image perlinNoise = GenImagePerlinNoise(screenWidth, screenHeight, 50, 50, 4.0f);
Image cellular = GenImageCellular(screenWidth, screenHeight, 32);
Texture2D textures[NUM_TEXTURES] = { 0 };
textures[0] = LoadTextureFromImage(verticalGradient);
textures[1] = LoadTextureFromImage(horizontalGradient);
textures[2] = LoadTextureFromImage(diagonalGradient);
textures[3] = LoadTextureFromImage(radialGradient);
textures[4] = LoadTextureFromImage(squareGradient);
textures[5] = LoadTextureFromImage(checked);
textures[6] = LoadTextureFromImage(whiteNoise);
textures[7] = LoadTextureFromImage(perlinNoise);
textures[8] = LoadTextureFromImage(cellular);
// Unload image data (CPU RAM)
UnloadImage(verticalGradient);
UnloadImage(horizontalGradient);
UnloadImage(diagonalGradient);
UnloadImage(radialGradient);
UnloadImage(squareGradient);
UnloadImage(checked);
UnloadImage(whiteNoise);
UnloadImage(perlinNoise);
UnloadImage(cellular);
int currentTexture = 0;
SetTargetFPS(60);
//---------------------------------------------------------------------------------------
// Main game loop
while (!WindowShouldClose())
{
// Update
//----------------------------------------------------------------------------------
if (IsMouseButtonPressed(MOUSE_BUTTON_LEFT) || IsKeyPressed(KEY_RIGHT))
{
currentTexture = (currentTexture + 1)%NUM_TEXTURES; // Cycle between the textures
}
//----------------------------------------------------------------------------------
// Draw
//----------------------------------------------------------------------------------
BeginDrawing();
ClearBackground(RAYWHITE);
DrawTexture(textures[currentTexture], 0, 0, WHITE);
DrawRectangle(30, 400, 325, 30, Fade(SKYBLUE, 0.5f));
DrawRectangleLines(30, 400, 325, 30, Fade(WHITE, 0.5f));
DrawText("MOUSE LEFT BUTTON to CYCLE PROCEDURAL TEXTURES", 40, 410, 10, WHITE);
switch (currentTexture)
{
case 0: DrawText("VERTICAL GRADIENT", 560, 10, 20, RAYWHITE); break;
case 1: DrawText("HORIZONTAL GRADIENT", 540, 10, 20, RAYWHITE); break;
case 2: DrawText("DIAGONAL GRADIENT", 540, 10, 20, RAYWHITE); break;
case 3: DrawText("RADIAL GRADIENT", 580, 10, 20, LIGHTGRAY); break;
case 4: DrawText("SQUARE GRADIENT", 580, 10, 20, LIGHTGRAY); break;
case 5: DrawText("CHECKED", 680, 10, 20, RAYWHITE); break;
case 6: DrawText("WHITE NOISE", 640, 10, 20, RED); break;
case 7: DrawText("PERLIN NOISE", 640, 10, 20, RED); break;
case 8: DrawText("CELLULAR", 670, 10, 20, RAYWHITE); break;
default: break;
}
EndDrawing();
//----------------------------------------------------------------------------------
}
// De-Initialization
//--------------------------------------------------------------------------------------
// Unload textures data (GPU VRAM)
for (int i = 0; i < NUM_TEXTURES; i++) UnloadTexture(textures[i]);
CloseWindow(); // Close window and OpenGL context
//--------------------------------------------------------------------------------------
return 0;
}From raylib 6.2. The original on GitHub.