tesseract view
There is no browser build of this example yet.
Is it the same as C?
- Desktop:verified The Zig version renders a final frame that is byte-identical to the C example.
- Browser:not checked yet The browser comparison does not cover this example yet.
//! raylib [models] example - tesseract view
//!
//! Zig-API translation of examples/models/models_tesseract_view.c (raylib 6.2).
//! Example licensed under an unmodified zlib/libpng license.
//! Copyright (c) 2024-2025 Timothy van der Valk (@arceryz) and Ramon Santamaria (@raysan5)
const rl = @import("raylib");
pub fn main() void {
// Initialization
const screen_width = 800;
const screen_height = 450;
rl.initWindow(screen_width, screen_height, "raylib [models] example - tesseract view");
defer rl.closeWindow(); // Close window and OpenGL context
// Define the camera to look into our 3d world
const camera: rl.Camera = .{
.position = .{ .x = 4.0, .y = 4.0, .z = 4.0 }, // Camera position
.target = .{ .x = 0.0, .y = 0.0, .z = 0.0 }, // Camera looking at point
.up = .{ .x = 0.0, .y = 0.0, .z = 1.0 }, // Camera up vector (rotation towards target)
.fovy = 50.0, // Camera field-of-view Y
.projection = .perspective, // Camera mode type
};
// Find the coordinates by setting XYZW to +-1
const tesseract = [16]rl.Vector4{
.{ .x = 1, .y = 1, .z = 1, .w = 1 }, .{ .x = 1, .y = 1, .z = 1, .w = -1 },
.{ .x = 1, .y = 1, .z = -1, .w = 1 }, .{ .x = 1, .y = 1, .z = -1, .w = -1 },
.{ .x = 1, .y = -1, .z = 1, .w = 1 }, .{ .x = 1, .y = -1, .z = 1, .w = -1 },
.{ .x = 1, .y = -1, .z = -1, .w = 1 }, .{ .x = 1, .y = -1, .z = -1, .w = -1 },
.{ .x = -1, .y = 1, .z = 1, .w = 1 }, .{ .x = -1, .y = 1, .z = 1, .w = -1 },
.{ .x = -1, .y = 1, .z = -1, .w = 1 }, .{ .x = -1, .y = 1, .z = -1, .w = -1 },
.{ .x = -1, .y = -1, .z = 1, .w = 1 }, .{ .x = -1, .y = -1, .z = 1, .w = -1 },
.{ .x = -1, .y = -1, .z = -1, .w = 1 }, .{ .x = -1, .y = -1, .z = -1, .w = -1 },
};
var transformed: [16]rl.Vector3 = undefined;
var w_values: [16]f32 = undefined;
rl.setTargetFPS(60); // Set our game to run at 60 frames-per-second
// Main game loop
while (!rl.windowShouldClose()) { // Detect window close button or ESC key
// Update
const rotation = rl.deg2rad * 45.0 * @as(f32, @floatCast(rl.getTime()));
for (tesseract, &transformed, &w_values) |vertex, *out, *w| {
var p = vertex;
// Rotate the XW part of the vector
const rot_xw = rl.math.vector2Rotate(.{ .x = p.x, .y = p.w }, rotation);
p.x = rot_xw.x;
p.w = rot_xw.y;
// Projection from XYZW to XYZ from perspective point (0, 0, 0, 3)
// NOTE: Trace a ray from (0, 0, 0, 3) > p and continue until W = 0
const c = 3.0 / (3.0 - p.w);
p.x = c * p.x;
p.y = c * p.y;
p.z = c * p.z;
// Split XYZ coordinate and W values later for drawing
out.* = .{ .x = p.x, .y = p.y, .z = p.z };
w.* = p.w;
}
// Draw
rl.beginDrawing();
defer rl.endDrawing();
rl.clearBackground(.ray_white);
rl.beginMode3D(camera);
defer rl.endMode3D();
for (tesseract, transformed, w_values, 0..) |v1, point, w, i| {
// Draw spheres to indicate the W value
rl.drawSphere(point, @abs(w * 0.1), .red);
for (tesseract, transformed, 0..) |v2, other, j| {
// Two lines are connected if they differ by 1 coordinate
// This way we dont have to keep an edge list
const diff = @as(u8, @intFromBool(v1.x == v2.x)) + @intFromBool(v1.y == v2.y) +
@intFromBool(v1.z == v2.z) + @intFromBool(v1.w == v2.w);
// Draw only differing by 1 coordinate and the lower index only (duplicate lines)
if (diff == 3 and i < j) rl.drawLine3D(point, other, .maroon);
}
}
}
}/*******************************************************************************************
*
* raylib [models] example - tesseract view
*
* NOTE: This example only works on platforms that support drag & drop (Windows, Linux, OSX, Html5?)
*
* Example complexity rating: [★★☆☆] 2/4
*
* Example originally created with raylib 6.0, last time updated with raylib 6.0
*
* Example contributed by Timothy van der Valk (@arceryz) and reviewed by Ramon Santamaria (@raysan5)
*
* Example licensed under an unmodified zlib/libpng license, which is an OSI-certified,
* BSD-like license that allows static linking with closed source software
*
* Copyright (c) 2024-2025 Timothy van der Valk (@arceryz) and Ramon Santamaria (@raysan5)
*
********************************************************************************************/
#include "raylib.h"
#include "raymath.h"
//------------------------------------------------------------------------------------
// Program main entry point
//------------------------------------------------------------------------------------
int main(void)
{
// Initialization
//--------------------------------------------------------------------------------------
const int screenWidth = 800;
const int screenHeight = 450;
InitWindow(screenWidth, screenHeight, "raylib [models] example - tesseract view");
// Define the camera to look into our 3d world
Camera camera = { 0 };
camera.position = (Vector3){ 4.0f, 4.0f, 4.0f }; // Camera position
camera.target = (Vector3){ 0.0f, 0.0f, 0.0f }; // Camera looking at point
camera.up = (Vector3){ 0.0f, 0.0f, 1.0f }; // Camera up vector (rotation towards target)
camera.fovy = 50.0f; // Camera field-of-view Y
camera.projection = CAMERA_PERSPECTIVE; // Camera mode type
// Find the coordinates by setting XYZW to +-1
Vector4 tesseract[16] = {
{ 1, 1, 1, 1 }, { 1, 1, 1, -1 },
{ 1, 1, -1, 1 }, { 1, 1, -1, -1 },
{ 1, -1, 1, 1 }, { 1, -1, 1, -1 },
{ 1, -1, -1, 1 }, { 1, -1, -1, -1 },
{ -1, 1, 1, 1 }, { -1, 1, 1, -1 },
{ -1, 1, -1, 1 }, { -1, 1, -1, -1 },
{ -1, -1, 1, 1 }, { -1, -1, 1, -1 },
{ -1, -1, -1, 1 }, { -1, -1, -1, -1 },
};
float rotation = 0.0f;
Vector3 transformed[16] = { 0 };
float wValues[16] = { 0 };
SetTargetFPS(60); // Set our game to run at 60 frames-per-second
//--------------------------------------------------------------------------------------
// Main game loop
while (!WindowShouldClose()) // Detect window close button or ESC key
{
// Update
//----------------------------------------------------------------------------------
rotation = DEG2RAD*45.0f*(float)GetTime();
for (int i = 0; i < 16; i++)
{
Vector4 p = tesseract[i];
// Rotate the XW part of the vector
Vector2 rotXW = Vector2Rotate((Vector2){ p.x, p.w }, rotation);
p.x = rotXW.x;
p.w = rotXW.y;
// Projection from XYZW to XYZ from perspective point (0, 0, 0, 3)
// NOTE: Trace a ray from (0, 0, 0, 3) > p and continue until W = 0
float c = 3.0f/(3.0f - p.w);
p.x = c*p.x;
p.y = c*p.y;
p.z = c*p.z;
// Split XYZ coordinate and W values later for drawing
transformed[i] = (Vector3){ p.x, p.y, p.z };
wValues[i] = p.w;
}
//----------------------------------------------------------------------------------
// Draw
//----------------------------------------------------------------------------------
BeginDrawing();
ClearBackground(RAYWHITE);
BeginMode3D(camera);
for (int i = 0; i < 16; i++)
{
// Draw spheres to indicate the W value
DrawSphere(transformed[i], fabsf(wValues[i]*0.1f), RED);
for (int j = 0; j < 16; j++)
{
// Two lines are connected if they differ by 1 coordinate
// This way we dont have to keep an edge list
Vector4 v1 = tesseract[i];
Vector4 v2 = tesseract[j];
int diff = (int)(v1.x == v2.x) + (int)(v1.y == v2.y) + (int)(v1.z == v2.z) + (int)(v1.w == v2.w);
// Draw only differing by 1 coordinate and the lower index only (duplicate lines)
if (diff == 3 && i < j) DrawLine3D(transformed[i], transformed[j], MAROON);
}
}
EndMode3D();
EndDrawing();
//----------------------------------------------------------------------------------
}
// De-Initialization
//--------------------------------------------------------------------------------------
CloseWindow(); // Close window and OpenGL context
//--------------------------------------------------------------------------------------
return 0;
}From raylib 6.2. The original on GitHub.